This plugin adds spreadsheet capabilities to TWiki topics. Formulae like %CALC{"\$INT(7/3)"}% are evaluated at page view time. They can be placed in table cells and outside of tables. In other words, this plugin provides general formula evaluation capability, not just classic spreadsheet functions.

Example:

Region: Sales:
Northeast 320
Northwest 580
South 240
Europe 610
Asia 220
Total: 1970

Interactive example:

Formula: %CALC{""}%
Result:     TWiki Guest
The formula next to "Total" is %CALC{"\$SUM( \$ABOVE() )"}%.
(you see the formula instead of the sum in case the plugin is not installed or not enabled.)

Syntax Rules

The action of this plugin is triggered by the %CALC{"..."}% variable, which gets rendered according to the built-in function(s) found between the quotes.

• Built-in function are of format \$FUNCNAME(parameter)
• Functions may be nested, such as %CALC{"\$SUM( R2:C\$COLUMN(0)..R\$ROW(-1):C\$COLUMN(0) )"}%
• Functions are evaluated from left to right, and from inside to outside if nested
• The function parameter can be text; a mathematical formula; a cell address; or a range of cell addresses
• Multiple parameters form a list; they are separated by a comma, followed by optional space, such as %CALC{"\$SUM( 3, 5, 7 )"}%
• A table cell can be addressed as R1:C1. Table address matrix:  R1:C1 R1:C2 R1:C3 R1:C4 R2:C1 R2:C2 R2:C3 R2:C4
• A table cell range is defined by two cell addresses separated by "..", e.g. "row 1 through 20, column 3" is: R1:C3..R20:C3
• Lists can refer to values and/or table cell ranges, such as %CALC{"\$SUM( 3, 5, \$T(R1:C7), R1:C11..R1:C15 )"}%
• Formulae can only reference cells in the current or preceeding row of the current table; they may not reference cells below the current table row
• Formulae can also be placed outside of tables; they can reference cells in the preceeding table
• Formulae can be placed in a FormattedSearch, but the CALC needs to be escaped. Learn how to use a CALC in a formatted search
• Plain text can be added, such as %CALC{"Total: \$SUM(\$ABOVE()) kg"}%

Built-in Functions

Conventions for Syntax:

• Required parameters are indicated in ( bold )
• Optional parameters are indicated in ( bold italic )

ABOVE( ) -- address range of cells above the current cell

• Syntax: \$ABOVE( )
• Example: %CALC{"\$SUM(\$ABOVE())"}% returns the sum of cells above the current cell
• Related: \$LEFT(), \$RIGHT()

AND( list ) -- logical AND of a list

• Syntax: \$AND( list )
• Example: %CALC{"\$AND(1, 0, 1)"}% returns 0
• Related: \$NOT(), \$IF(), \$OR()

AVERAGE( list ) -- average of a list or a range of cells

• Syntax: \$AVERAGE( list )
• Example: %CALC{"\$AVERAGE(R2:C5..R\$ROW(-1):C5)"}% returns the average of column 5, excluding the title row
• Related: \$LIST(), \$MAX(), \$MEDIAN(), \$MIN()

CHAR( number ) -- ASCII character represented by number

• Syntax: \$CHAR( number )
• Example: Example: %CALC{"\$CHAR(97)"}% returns a
• Related: \$CODE()

CODE( text ) -- ASCII numeric value of character

• The ASCII numeric value of the first character in text
• Syntax: \$CODE( text )
• Example: %CALC{"\$CODE(abc)"}% returns 97
• Related: \$CHAR()

COLUMN( offset ) -- current column number

• The current table column number with an optional offset
• Syntax: \$COLUMN( offset )
• Example: %CALC{"\$COLUMN()"}% returns 2 for the second column
• Related: \$ROW(), \$T()

COUNTITEMS( list ) -- count individual items in a list

• Syntax: \$COUNTITEMS( list )
• Example: %CALC{"\$COUNTITEMS(\$ABOVE())"}% returns Closed: 1, Open: 2 assuming one cell above the current cell contains Closed and two cells contain Open
• Related: \$COUNTSTR(), \$LIST()

COUNTSTR( list, str ) -- count the number of cells in a list equal to a given string

• Count the number of cells in a list equal to a given string (if str is specified), or counts the number of non empty cells in a list
• Syntax: \$COUNTSTR( list, str )
• Example: %CALC{"\$COUNTSTR(\$ABOVE())"}% counts the number of non empty cells above the current cell
• Example: %CALC{"\$COUNTSTR(\$ABOVE(), DONE)"}% counts the number of cells equal to DONE
• Related: \$COUNTITEMS(), \$LIST()

DEF( list ) -- find first non-empty list item or cell

• Returns the first list item or cell reference that is not empty
• Syntax: \$DEF( list )
• Example: %CALC{"\$DEF(R1:C1..R1:C3)"}%
• Related: \$COUNTSTR(), \$LISTIF(), \$LIST()

EMPTY( text ) -- test for empty text

• Returns 1 if text is empty, or 0 if not
• Syntax: \$EMPTY( text )
• Example: %CALC{"\$EMPTY(foo)"}% returns 0
• Example: %CALC{"\$EMPTY()"}% returns 1
• Example: %CALC{"\$EMPTY(\$TRIM( ))"}% returns 1
• Related: \$EXACT(), \$IF(), \$TRIM()

EVAL( formula ) -- evaluate a simple mathematical formula

• Addition, substraction, multiplication, division and modulus of numbers are supported. Any nesting is permitted
• Numbers may be decimal integers (1234), binary integers (0b1110011), octal integers (01234), hexadecimal integers (0x1234) or of exponential notation (12.34e-56)
• Syntax: \$EVAL( formula )
• Example: %CALC{"\$EVAL( (5 * 3) / 2 + 1.1 )"}% returns 8.6
• Related: \$EXEC(), \$INT(), \$MOD(), \$ROUND(), \$VALUE()

EXACT( text1, text2 ) -- compare two text strings

• Compares two text strings and returns 1 if they are exactly the same, or 0 if not
• Syntax: \$EXACT( text1, text2 )
• Example: %CALC{"\$EXACT(foo, Foo)"}% returns 0
• Example: %CALC{"\$EXACT(foo, \$LOWER(Foo))"}% returns 1
• Related: \$EMPTY(), \$IF(), \$TRIM()

EXEC( formula ) -- execute a spreadsheet formula

• Execute a spreadsheet formula, typically retrieved from a variable. This can be used to store a formula in a variable once and execute it many times using different parameters.
• Syntax: \$EXEC( formula )
• Example: %CALC{"\$SET(msg, \$NOEXEC(Hi \$GET(name)))"}% sets the msg variable with raw formula Hi \$GET(name)
• Example: %CALC{"\$SET(name, Tom) \$EXEC(\$GET(msg))"}% executes content of msg variable and returns Hi Tom
• Example: %CALC{"\$SET(name, Jerry) \$EXEC(\$GET(msg))"}% returns Hi Jerry
• Related: \$EVAL(), \$GET(), \$NOEXEC(), \$SET()

EXISTS( topic ) -- check if topic exists

• Topic can be TopicName or a Web.TopicName. Current web is used if web is not specified.
• Syntax: \$EXISTS( topic )
• Example: %CALC{"\$EXISTS(WebHome)"}% returns 1
• Example: %CALC{"\$EXISTS(ThisDoesNotExist)"}% returns 0
• Related: \$EXACT(), \$IF(), \$TRIM()

EXP( num ) -- exponent (e) raised to the power of a number

• EXP is the inverse of the LN function
• Syntax: \$EXP( num )
• Example: %CALC{"\$EXP(1)"}% returns 2.71828182845905
• Related: \$LN(), \$LOG()

FIND( string, text, start ) -- find one string within another string

• Finds one text string, within another text, and returns the number of the starting position of string, from the first character of text. This search is case sensitive and is not a regular expression search; use \$SEARCH() for regular expression searching. Starting position is 1; a 0 is returned if nothing is matched.
• Syntax: \$FIND( string, text, start )
• Example: %CALC{"\$FIND(f, fluffy)"}% returns 1
• Example: %CALC{"\$FIND(f, fluffy, 2)"}% returns 4
• Example: %CALC{"\$FIND(@, fluffy, 1)"}% returns 0
• Related: \$INSERTSTRING(), \$LEFTSTRING(), \$REPLACE(), \$RIGHTSTRING(), \$SUBSTRING(), \$SEARCH()

FORMAT( type, precision, number ) -- format a number to a certain type and precision

• Supported type:
• COMMA for comma format, such as 12,345.68
• DOLLAR for Dollar format, such as \$12,345.68
• KB for Kilo Byte format, such as 1205.63 KB
• MB for Mega Byte format, such as 1.18 MB
• KBMB for Kilo/Mega/Giga/Tera Byte auto-adjust format
• NUMBER for number, such as 12345.7
• PERCENT for percent format, such as 12.3%
• The precision indicates the the number of digits after the dot
• Syntax: \$FORMAT( type, prec, number )
• Example: %CALC{"\$FORMAT(COMMA, 2, 12345.6789)"}% returns 12,345.68
• Example: %CALC{"\$FORMAT(DOLLAR, 2, 12345.67)"}% returns \$12,345.68
• Example: %CALC{"\$FORMAT(KB, 2, 1234567)"}% returns 1205.63 KB
• Example: %CALC{"\$FORMAT(MB, 2, 1234567)"}% returns 1.18 MB
• Example: %CALC{"\$FORMAT(KBMB, 2, 1234567)"}% returns 1.18 MB
• Example: %CALC{"\$FORMAT(KBMB, 2, 1234567890)"}% returns 1.15 GB
• Example: %CALC{"\$FORMAT(NUMBER, 1, 12345.67)"}% returns 12345.7
• Example: %CALC{"\$FORMAT(PERCENT, 1, 0.1234567)"}% returns 12.3%
• Related: \$FORMATTIME(), \$FORMATTIMEDIFF(), \$ROUND()

FORMATTIME( serial, text ) -- convert a serialized date into a date string

• The following variables in text are expanded:
• \$second - seconds, 00..59
• \$minute - minutes, 00..59
• \$hour - hours, 00..23
• \$day - day of month, 01..31
• \$month - month, 01..12
• \$mon - month in text format, Jan..Dec
• \$year - 4 digit year, 1999
• \$ye - 2 digit year, 99
• \$wd - day number of the week, 1 for Sunday, 2 for Monday, etc
• \$wday - day of the week, Sun..Sat
• \$weekday - day of the week, Sunday..Saturday
• \$yearday - day of the year, 1..365, or 1..366 in leap years
• \$isoweek - ISO 8601 week number, one or two digits, 1..53
• \$isoweek(format) - formatted ISO 8601 week number. These variables are expanded in format:
• \$isoweek(\$year) - year of ISO 8601 week number, such as 2009 for 2010-01-03
• \$isoweek(\$wk) - 2 digit ISO 8601 week number, such as 53 for 2010-01-03
• \$isoweek(\$day) - day of ISO 8601 week number, starting with 1 for Monday, such as 7 for 2010-01-03
• \$isoweek(\$iso) - full year-week ISO week number, such as 2009-W53 for 2010-01-03
• \$isoweek(\$yearW\$wk\$day) - full year-week-day ISO week number, such as 2009W537 for 2010-01-03
• \$isoweek(\$year-W\$wk-\$day) - full year-week-day ISO week number, such as 2009-W53-7 for 2010-01-03
• \$isoweek(\$year-W\$wk) - year-week ISO 8601 week number, such as 2009-W53 for 2010-01-03
• Date is assumed to be server time; add GMT to text to indicate Greenwich time zone, or use \$FORMATGMTIME().
• Syntax: \$FORMATTIME( serial, text )
• Example: %CALC{"\$FORMATTIME(0, \$year/\$month/\$day GMT)"}% returns 1970/01/01 GMT
• Related: \$FORMATGMTIME(), \$TIME(), \$FORMATTIMEDIFF(), \$TIMEADD(), \$TIMEDIFF(), \$TODAY()

FORMATTIMEDIFF( unit, precision, time ) -- convert elapsed time to a string

• Convert elapsed time to a human readable format, such as: 12 hours and 3 minutes
• The input unit can be second, minute, hour, day, month, year. Note: An approximation is used for month and year calculations.
• The precision indicates the number of output units to use
• Syntax: \$FORMATTIMEDIFF( unit, precision, time )
• Example: %CALC{"\$FORMATTIMEDIFF(min, 1, 200)"}% returns 3 hours
• Example: %CALC{"\$FORMATTIMEDIFF(min, 2, 200)"}% returns 3 hours and 20 minutes
• Example: %CALC{"\$FORMATTIMEDIFF(min, 1, 1640)"}% returns 1 day
• Example: %CALC{"\$FORMATTIMEDIFF(min, 2, 1640)"}% returns 1 day and 3 hours
• Example: %CALC{"\$FORMATTIMEDIFF(min, 3, 1640)"}% returns 1 day, 3 hours and 20 minutes
• Related: \$FORMATTIME(), \$TIME(), \$TIMEADD(), \$TIMEDIFF()

GET( name ) -- get the value of a previously set variable

• Specify the variable name (alphanumeric characters and underscores). An empty string is returned if the variable does not exist. Use \$SET() to set a variable first. Unlike table ranges, variables live for the time of the page view and persist across tables, i.e. you can use it to summarize results across several tables.
• Syntax: \$GET( name )
• Example: %CALC{"\$GET(my_total)"}% returns the value of the my_total variable
• Related: \$EXEC(), \$NOEXEC(), \$SET(), \$SETIFEMPTY(), \$SETM()

IF( condition, value if true, value if 0 ) -- return a value based on a condition

• The condition can be a number (where 0 means condition not met), or two numbers with a comparison operator < (less than), <= (less than or equal), == (equal), != (not equal), >= (greater than or equal), > (greater than).
• Syntax: \$IF( condition, value if true, value if 0 )
• Example: %CALC{"\$IF(\$T(R1:C5) > 1000, Over Budget, OK)"}% returns Over Budget if value in R1:C5 is over 1000, OK if not
• Example: %CALC{"\$IF(\$EXACT(\$T(R1:C2),), empty, \$T(R1:C2))"}% returns the content of R1:C2 or empty if empty
• Example: %CALC{"\$SET(val, \$IF(\$T(R1:C2) == 0, zero, \$T(R1:C2)))"}% sets a variable conditionally
• Related: \$AND(), \$EMPTY(), \$EXACT(), \$LISTIF(), \$NOT(), \$OR()

INT( formula ) -- evaluate formula and round down to nearest integer

• Addition, substraction, multiplication, division and modulus of numbers are supported. Any nesting is permitted
• Numbers may be decimal integers (1234), binary integers (0b1110011), octal integers (01234), hexadecimal integers (0x1234) or of exponential notation (12.34e-56)
• If you expect a single decimal integer value with leading zeros, use \$INT( \$VALUE( number ) )
• Syntax: \$INT( formula )
• Example: %CALC{"\$INT(10 / 4)"}% returns 2
• Example: %CALC{"\$INT(\$VALUE(09))"}% returns 9
• Related: \$EVAL(), \$ROUND(), \$VALUE()

LEFT( ) -- address range of cells to the left of the current cell

• Syntax: \$LEFT( )
• Example: %CALC{"\$SUM(\$LEFT())"}% returns the sum of cells to the left of the current cell
• Related: \$ABOVE(), \$RIGHT()

LENGTH( text ) -- length of text in bytes

• Syntax: \$LENGTH( text )
• Example: %CALC{"\$LENGTH(abcd)"}% returns 4
• Related: \$LISTSIZE()

LISTJOIN( separator, list ) -- convert a list into a string

• By default, list items are separated by a comma and a space. Use this function to indicate a specific separator string, which may include \$comma for comma, \$n for newline, \$sp for space, and \$nop for a no-operation (join list without a separator).
• Syntax: \$LISTJOIN( separator, list )
• Example: %CALC{"\$LISTJOIN(\$n, Apple, Orange, Apple, Kiwi)"}% returns the four items separated by new lines
• Related: \$LIST(), \$LISTSIZE()

LN( num ) -- natural logarithm of a number

• LN is the inverse of the EXP function
• Syntax: \$LN( num )
• Example: %CALC{"\$LN(10)"}% returns 2.30258509299405
• Related: \$EXP(), \$LOG()

LOG( num, base ) -- logarithm of a number to a given base

• base-10 logarithm of a number (if base is 0 or not specified), else logarithm of a number to the given base
• Syntax: \$LOG( num, base )
• Example: %CALC{"\$LOG(1000)"}% returns 3
• Example: %CALC{"\$LOG(16, 2)"}% returns 4
• Related: \$EXP(), \$LN()

MOD( num, divisor ) -- reminder after dividing num by divisor

• Syntax: \$MOD( num, divisor )
• Example: %CALC{"\$MOD(7, 3)"}% returns 1
• Related: \$EVAL()

NOEXEC( formula ) -- do not execute a spreadsheet formula

• Prevent a formula from getting executed. This is typically used to store a raw formula in a variable for later use as described in \$EXEC().
• Syntax: \$NOEXEC( formula )
• Example: %CALC{"\$SET(msg, \$NOEXEC(Hi \$GET(name)))"}% sets the msg variable with the formula Hi \$GET(name) without executing it
• Related: \$EVAL(), \$EXEC(), \$GET(), \$SET()

NOP( text ) -- no-operation

• Useful to change the order of plugin execution. For example, it allows preprocessing to be done before %SEARCH{}% is evaluated. The percent character '%' can be escaped with \$percnt. The quote character '"' can be escaped with \$quot.
• Syntax: \$NOP( text )

NOT( num ) -- reverse logic of a number

• Returns 0 if num is not zero, 1 if zero
• Syntax: \$NOT( num )
• Example: %CALC{"\$NOT(0)"}% returns 1
• Related: \$AND(), \$EMPTY(), \$IF(), \$OR()

OR( list ) -- logical OR of a list

• Syntax: \$OR( list )
• Example: %CALC{"\$OR(1, 0, 1)"}% returns 1
• Related: \$AND(), \$IF(), \$NOT()

PERCENTILE( num, list ) -- percentile of a list or range of cells

• Calculates the num-th percentile, useful to establish a threshold of acceptance. num is the percentile value, range 0..100
• Syntax: \$PERCENTILE( num, list )
• Example: %CALC{"\$PERCENTILE(75, 400, 200, 500, 100, 300)"}% returns 450
• Related: \$LIST(), \$MAX(), \$MEDIAN(), \$MIN()

PI( ) -- mathematical constant Pi, 3.14159265358979

• Syntax: \$PI( )
• Example: %CALC{"\$PI()"}% returns 3.14159265358979

PRODUCT( list ) -- product of a list or range of cells

• Syntax: \$PRODUCT( list )
• Example: To calculate the product of the cells to the left of the current one use %CALC{"\$PRODUCT(\$LEFT())"}%
• Related: \$LIST(), \$PRODUCT(), \$SUM(), \$SUMPRODUCT()

PROPER( text ) -- properly capitalize text

• Capitalize letters that follow any character other than a letter; convert all other letters to lowercase letters
• Syntax: \$PROPER( text )
• Example: %CALC{"\$PROPER(a small STEP)"}% returns A Small Step
• Example: %CALC{"\$PROPER(f1 (formula-1))"}% returns F1 (Formula-1)
• Related: \$LOWER(), \$PROPERSPACE(), \$TRIM(), \$UPPER()

PROPERSPACE( text ) -- properly space out WikiWords

• Properly spaces out WikiWords preceeded by white space, parenthesis, or ][. Words listed in the DONTSPACE TWikiPreferences variable or DONTSPACE plugins setting are excluded
• Syntax: \$PROPERSPACE( text )
• Example: Assuming DONTSPACE contains MacDonald: %CALC{"\$PROPERSPACE(Old MacDonald had a ServerFarm, EeEyeEeEyeOh)"}% returns Old MacDonald had a Server Farm, Ee Eye Ee Eye Oh
• Related: \$LOWER(), \$PROPER(), \$TRIM(), \$UPPER()

REPEAT( text, num ) -- repeat text a number of times

• Syntax: \$REPEAT( text, num )
• Example: %CALC{"\$REPEAT(/\, 5)"}% returns /\/\/\/\/\

RIGHT( ) -- address range of cells to the right of the current cell

• Syntax: \$RIGHT( )
• Example: %CALC{"\$SUM(\$RIGHT())"}% returns the sum of cells to the right of the current cell
• Related: \$ABOVE(), \$LEFT()

ROUND( formula, digits ) -- round a number

• Evaluates a simple formula and rounds the result up or down to the number of digits if digits is positive; to the nearest integer if digits is missing; or to the left of the decimal point if digits is negative
• Syntax: \$ROUND( formula, digits )
• Example: %CALC{"\$ROUND(3.15, 1)"}% returns 3.2
• Example: %CALC{"\$ROUND(3.149, 1)"}% returns 3.1
• Example: %CALC{"\$ROUND(-2.475, 2)"}% returns -2.48
• Example: %CALC{"\$ROUND(34.9, -1)"}% returns 30
• Related: \$INT(), \$FORMAT()

ROW( offset ) -- current row number

• The current table row number with an optional offset
• Syntax: \$ROW( offset )
• Example: To get the number of rows excluding table heading (first row) and summary row (last row you are in), write: %CALC{"\$ROW(-2)"}%
• Related: \$COLUMN(), \$T()

SEARCH( string, text, start ) -- search a string within a text

• Finds one text string, within another text, and returns the number of the starting position of string, from the first character of text. This search is a RegularExpression search; use \$FIND() for non-regular expression searching. Starting position is 1; a 0 is returned if nothing is matched
• Syntax: \$SEARCH( string, text, start )
• Example: %CALC{"\$SEARCH([uy], fluffy)"}% returns 3
• Example: %CALC{"\$SEARCH([uy], fluffy, 3)"}% returns 6
• Example: %CALC{"\$SEARCH([abc], fluffy,)"}% returns 0
• Related: \$FIND(), \$INSERTSTRING(), \$LEFTSTRING(), \$REPLACE(), \$RIGHTSTRING(), \$SUBSTRING()

SET( name, value ) -- set a variable for later use

• Specify the variable name (alphanumeric characters and underscores) and the value. The value may contain a formula; formulae are evaluated before the variable assignment; see \$NOEXEC() if you want to prevent that. This function returns no output. Use \$GET() to retrieve variables. Unlike table ranges, variables live for the time of the page view and persist across tables, i.e. you can use it to summarize results across several tables and also across included topics
• Syntax: \$SET( name, value )
• Example: %CALC{"\$SET(my_total, \$SUM(\$ABOVE()))"}% sets the my_total variable to the sum of all table cells located above the current cell and returns an empty string
• Related: \$EXEC(), \$GET(), \$NOEXEC(), \$SETIFEMPTY(), SETM()

SETIFEMPTY( name, value ) -- set a variable only if empty

• Specify the variable name (alphanumeric characters and underscores) and the value.
• Syntax: \$SETIFEMPTY( name, value )
• Example: %CALC{"\$SETIFEMPTY(result, default)"}% sets the result variable to default if the variable is empty or 0; in any case an empty string is returned
• Related: \$GET(), \$SET()

SETM( name, formula ) -- update an existing variable based on a formula

• Specify the variable name (alphanumeric characters and underscores) and the formula. The formula must start with an operator to + (add), - (subtract), * (multiply), or / (divide) something to the variable. This function returns no output. Use \$GET() to retrieve variables
• Syntax: \$SETM( name, formula )
• Example: %CALC{"\$SETM(total, + \$SUM(\$LEFT()))"}% adds the sum of all table cells on the left to the total variable, and returns an empty string
• Related: \$GET(), \$SET(), \$SETIFEMPTY()

SQRT( num ) -- square root of a number

• Syntax: \$SQRT( num )
• Example: %CALC{"\$SQRT(16)"}% returns 4

SUBSTITUTE( text, old, new, instance, option ) -- substitute text

• Substitutes new text for old text in a text string. instance specifies which occurance of old you want to replace. If you specify instance, only that instance is replaced. Otherwise, every occurance is changed to the new text. A literal search is performed by default; a RegularExpression search if the option is set to r
• Syntax: \$SUBSTITUTE( text, old, new, instance, option )
• Example: %CALC{"\$SUBSTITUTE(Good morning, morning, day)"}% returns Good day
• Example: %CALC{"\$SUBSTITUTE(Q2-2002, 2, 3)"}% returns Q3-3003
• Example: %CALC{"\$SUBSTITUTE(Q2-2002,2, 3, 3)"}% returns Q2-2003
• Example: %CALC{"\$SUBSTITUTE(abc123def, [0-9], 9, , r)"}% returns abc999def
• Related: \$INSERTSTRING(), \$LEFTSTRING(), \$REPLACE(), \$RIGHTSTRING(), \$SUBSTRING(), \$TRANSLATE()

SUM( list ) -- sum of a list or range of cells

• Syntax: \$SUM( list )
• Example: To sum up column 5 excluding the title row, write %CALC{"\$SUM(R2:C5..R\$ROW(-1):C5)"}% in the last row; or simply %CALC{"\$SUM(\$ABOVE())"}%
• Related: \$LIST(), \$PRODUCT(), \$SUMPRODUCT(), \$WORKINGDAYS()

SUMDAYS( list ) -- sum the days in a list or range of cells

• The total number of days in a list or range of cells containing numbers of hours, days or weeks. The default unit is days; units are indicated by a h, hours, d, days, w, weeks suffix. One week is assumed to have 5 working days, one day 8 hours
• Syntax: \$SUMDAYS( list )
• Example: %CALC{"\$SUMDAYS(2w, 1, 2d, 4h)"}% returns 13.5, the evaluation of (2*5 + 1 + 2 + 4/8)
• Related: \$SUM(), \$TIME(), \$FORMATTIME()

SUMPRODUCT( list, list ) -- scalar product on ranges of cells

• Syntax: \$SUMPRODUCT( list, list, list... )
• Example: %CALC{"\$SUMPRODUCT(R2:C1..R4:C1, R2:C5..R4:C5)"}% evaluates and returns the result of (\$T(R2:C1) * \$T(R2:C5) + \$T(R3:C1) * \$T(R3:C5) + \$T(R4:C1) * \$T(R4:C5))
• Related: \$LIST(), \$PRODUCT(), \$SUM()

T( address ) -- content of a cell

• Example: %CALC{"\$T(R1:C5)"}% returns the text in cell R1:C5
• Related: \$COLUMN(), \$ROW()

TRANSLATE( text, from, to ) -- translate text from one set of characters to another

• The translation is done from a set to a set, one character by one. The text may contain commas; all three parameters are required. In the from and to parameters you can add token \$comma for comma, \$sp for space, and \$n for newline
• Syntax: \$TRANSLATE( text, from, to )
• Example: %CALC{"\$TRANSLATE(boom,bm,cl)"}% returns cool
• Example: %CALC{"\$TRANSLATE(one, two,\$comma,;)"}% returns one; two
• Related: \$INSERTSTRING(), \$LEFTSTRING(), \$REPLACE(), \$RIGHTSTRING(), \$SUBSTRING(), \$SUBSTITUTE()

TIME( text ) -- convert a date string into a serialized date number

• Serialized date is seconds since the Epoch, e.g. midnight, 01 Jan 1970. Current time is taken if the date string is empty. Supported date formats: 31 Dec 2009; 31 Dec 2009 GMT; 31 Dec 09; 31-Dec-2009; 31/Dec/2009; 31 Dec 2003 - 23:59; 31 Dec 2003 - 23:59:59; 2009/12/31; 2009-12-31; 2009/12/31; 2009/12/31 23:59; 2009/12/31 - 23:59; 2009-12-31-23-59; 2009/12/31 - 23:59:59; 2009.12.31.23.59.59. DOY (Day of Year) formats: DOY2003.365, DOY2003.365.23.59, DOY2003.365.23.59.59. Date is assumed to be server time; add GMT to indicate Greenwich time zone
• Syntax: \$TIME( text )
• Example: %CALC{"\$TIME(2003/10/14 GMT)"}% returns 1066089600
• Related: \$FORMATGMTIME(), \$FORMATTIME(), \$FORMATTIMEDIFF(), \$TIMEADD(), \$TIMEDIFF(), \$TODAY(), \$WORKINGDAYS()

TIMEADD( serial, value, unit ) -- add a value to a serialized date

• The unit is seconds if not specified; unit can be second, minute, hour, day, week, month, year. Note: An approximation is used for month and year calculations
• Syntax: \$TIMEADD( serial, value, unit )
• Example: %CALC{"\$TIMEADD(\$TIME(), 2, week)"}% returns the serialized date two weeks from now
• Related: \$FORMATTIME(), \$FORMATGMTIME(), \$TIME(), \$TIMEDIFF(), \$TODAY()

TIMEDIFF( serial_1, serial_2, unit ) -- time difference between two serialized dates

• The unit is seconds if not specified; unit can be specified as in \$TIMEADD().
• Notes: An approximation is used for month and year calculations. Use \$ROUND() to round day unit to account for daylight savings time change. Use \$FORMAT(), \$FORMATTIMEDIFF() or \$INT() to format real numbers
• Syntax: \$TIMEDIFF( serial_1, serial_2, unit )
• Example: %CALC{"\$TIMEDIFF(\$TIME(), \$EVAL(\$TIME()+90), minute)"}% returns 1.5
• Example: %CALC{"\$ROUND(\$TIMEDIFF(\$TIME(2009/03/06),\$TIME(2009/03/13), day))"}% returns 7 (or 6.95833333333333 without the \$ROUND())
• Related: \$FORMAT(), \$FORMATGMTIME(), \$FORMATTIME(), \$FORMATTIMEDIFF(), \$INT(), \$TIME(), \$TIMEADD(), \$TODAY(), \$WORKINGDAYS()

TODAY( ) -- serialized date of today at midnight GMT

• In contrast, the related \$TIME() returns the serialized date of today at the current time, e.g. it includes the number of seconds since midnight GMT
• Syntax: \$TODAY( )
• Example: %CALC{"\$TODAY()"}% returns the number of seconds since Epoch
• Related: \$FORMATTIME(), \$FORMATGMTIME(), \$TIME(), \$TIMEADD(), \$TIMEDIFF()

TRIM( text ) -- trim spaces from text

• Removes all spaces from text except for single spaces between words
• Syntax: \$TRIM( text )
• Example: %CALC{"\$TRIM( eat  spaces  )"}% returns eat spaces
• Related: \$EMPTY(), \$EXACT(), \$PROPERSPACE()

VALUE( text ) -- convert text to number

• Syntax: \$VALUE( text )
• Example: %CALC{"\$VALUE(US\$1,200)"}% returns 1200
• Example: %CALC{"\$VALUE(PrjNotebook1234)"}% returns 1234
• Example: %CALC{"\$VALUE(Total: -12.5)"}% returns -12.5
• Related: \$EVAL(), \$INT()

WORKINGDAYS( serial_1, serial_2 ) -- working days between two serialized dates

• Working days are Monday through Friday (sorry, Israel!)
• Syntax: \$WORKINGDAYS( serial_1, serial_2 )
• Example: %CALC{"\$WORKINGDAYS(\$TIME(2004/07/15), \$TIME(2004/08/03))"}% returns 13
• Related: \$SUMDAYS(), \$TIME(), \$TIMEDIFF()

FAQ

Can I use CALC in a formatted search?

Specifically, how can I output some conditional text in a FormattedSearch?

You need to escape the CALC so that it executes once per search hit. This can be done by escaping the % signs of %CALC{...}% with \$percnt. For example, to execute \$IF(\$EXACT(\$formfield(Tested), Yes), %PUBURL%/%SYSTEMWEB%/TWikiDocGraphics/choice-yes.gif, %PUBURL%/%SYSTEMWEB%/TWikiDocGraphics/choice-no.gif) in the format="" parameter, write this:

%SEARCH{ .... format="| \$topic | \$percntCALC{\$IF(\$EXACT(\$formfield(Tested), Yes), %PUBURL%/%SYSTEMWEB%/TWikiDocGraphics/choice-yes.gif, %PUBURL%/%SYSTEMWEB%/TWikiDocGraphics/choice-no.gif)}\$percnt |" }%

How can I easily repeat a formula in a table?

To repeat the same formula in all cells of a table row define the formula once in a preferences setting and use that in the CALC. The preferences setting can be defined at the site level, web level or topic level, and may be hidden in HTML comments. Example:

<!--
* Set MYFORMULA = \$EVAL(\$SUBSTITUTE(...etc...))
-->
| A | 1 | %CALC{%MYFORMULA%}% |
| B | 2 | %CALC{%MYFORMULA%}% |
| C | 3 | %CALC{%MYFORMULA%}% |

CALC in Included Topics

By default, CALCs in an included topic are evaluated with delay. The SKIPINCLUDE setting tells the plugin to evaluate the CALCs once all INCLUDEs are processed. This default behavior is chosen so that it is possible to compose a bigger table from several includes and do some spreadsheet calculation over the whole table. Attention: You can get unexpected results if you INCLUDE a topic that has other variables taking action on CALCs. For example, a CHART in an included topic sees unprocessed CALCs, which may result in a chart with incorrect values. To get he desired result you need to set the following preference setting in the topic that includes the topic containing the CHART:

This setting tells the SpreadSheetPlugin to process the CALCs in the included page, e.g. it will not delay the evaluation of the formulae.

Bug Tracking Example

Bug#: Priority: Subject: Status: Days to fix
Bug:1231 Low File Open ... Open 3
Bug:1232 High Memory Window ... Fixed 2
Bug:1233 Medium Usability issue ... Assigned 5
Bug:1234 High No arrange ... Fixed 1
Total: 4 High: 2
Low: 1
Medium: 1
. Assigned: 1
Fixed: 2
Open: 1
Total: 11

The last row is defined as:

| Total: %CALC{"\$ROW(-2)"}% \
| %CALC{"\$COUNTITEMS( R2:C\$COLUMN()..R\$ROW(-1):C\$COLUMN() )"}% | . \
| %CALC{"\$COUNTITEMS( R2:C\$COLUMN()..R\$ROW(-1):C\$COLUMN() )"}% \
|  Total: %CALC{"\$SUM( R2:C\$COLUMN()..R\$ROW(-1):C\$COLUMN() )"}% |

Above table is created manually. The table can be build dynamically with a formatted search, or by a plugin that pulls data from an external source, such as a bug tracking system.

Plugin Settings

Plugin settings are stored as preferences variables. To reference a plugin setting write %<plugin>_<setting>%, i.e. %SPREADSHEETPLUGIN_SHORTDESCRIPTION%

• One line description, is shown in the TextFormattingRules topic:
• Set SHORTDESCRIPTION = Add spreadsheet calculation like "\$SUM( \$ABOVE() )" to TWiki tables or anywhere in topic text

• Debug plugin: (See output in data/debug.txt)
• Set DEBUG = 0

• Do not handle %CALC{}% variable in included topic while including topic: (default: 1) (See note CALC in Included Topics)
• Set SKIPINCLUDE = 1

• WikiWords to exclude from being spaced out by the \$PROPERSPACE(text) function. This comma delimited list can be overloaded by a DONTSPACE preferences variable:
• Set DONTSPACE = CodeWarrior, MacDonald, McIntosh, RedHat, SuSE

Plugin Installation Instructions

Note: You do not need to install anything on the browser to use this plugin. Below installation instructions are for the administrator who needs to install this plugin on the TWiki server.

File: Description:
• TWiki 4 and up: Visit configure in your TWiki installation, and enable the plugin in the {Plugins} section.
• Test if the "Total" in the first table in this topic is correct.

Plugin Info   Edit Attach 